[
   stripcomments.bf - Don Yang (uguu.org)

   Remove non-BF characters from stdin and write to stdout.

      43  44  45  46  60  62  91  93
      +   ,   -   .   <   >   [   ]

   When converted to C, the nesting level is too deep for MSVC6 to compile,
   but GCC compiles just fine.

   09/02/04
]

Initialize
+++++[->++++++++ [>+>+>+>+>+>+>+>+<<<<<<<<-] <]
>>+++
>++++
>+++++
>++++++     |0 0 43 44 45 ^46 40 40 40 40

<<<<++++++++++[->>>>>++>++>+++++>+++++ <<<<<<<<]
>>>>>>++
>+
>+++>       |0 0 43 44 45 46 60 62 91 93 ^


Process loop
,+[
   -[ 0 -[ 1 -[ 2 -[ 3 -[ 4 -[ 5 -[ 6 -[ 7 -[ 8 -[ 9
   -[10 -[11 -[12 -[13 -[14 -[15 -[16 -[17 -[18 -[19
   -[20 -[21 -[22 -[23 -[24 -[25 -[26 -[27 -[28 -[29
   -[30 -[31 -[32 -[33 -[34 -[35 -[36 -[37 -[38 -[39
   -[40 -[41 -[42


   test 43 >+< -
   [
      test 44 -
      [
         test 45 -
         [
            test 46 -
            [
               >-<
               -[47 -[48 -[49 -[50 -[51 -[52
               -[53 -[54 -[55 -[56 -[57 -[58 -[59

               test 60 >+< -
               [
                  >-< -[61

                  test 62 >+< -[
                     >-<
                     -[63 -[64 -[65 -[66 -[67 -[68 -[69 -[70 -[71 -[72
                     -[73 -[74 -[75 -[76 -[77 -[78 -[79 -[80 -[81 -[82
                     -[83 -[84 -[85 -[86 -[87 -[88 -[89 -[90

                     test 91 >+< -[
                        >-<
                        -[92

                        test 93 >+< -[
                           char greater than 93
                           >-<[-]
                        ]
                        >[
                           char == 93
                           < <.
                           > >-
                        ]<

                        ]
                     ]
                     >[
                        char == 91
                        < <<.
                        > >>-
                     ]<

                     ]]]]]]]]]]]]]]]]]]]]]]]]]]]]
                  ]
                  >[
                     char == 62
                     < <<<.
                     > >>>-
                  ]<

                  ]
               ]
               >[
                  char == 60
                  < <<<<.
                  > >>>>-
               ]<

               ]]]]]]]]]]]]]
            ]
            >[
               char == 46
               < <<<<<.
               > >>>>>-
            ]<
         ]
         >[
            char == 45
            < <<<<<<.
            > >>>>>>-
         ]<
      ]
      >[
         char == 44
         < <<<<<<<.
         > >>>>>>>-
      ]<
   ]
   >[
      char == 43
      < <<<<<<<<.
      > >>>>>>>>-
   ]<

   ]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]]

,+]

Output newline at the end for aesthetics
++++++++++.